PC Answers 1998 January/PC Answers Issue 49 Cover CD January 1998.iso/Apps/Director/DATA.Z/Widget Wizard.dir/WidgtBehaviors_78_UI Rollover Change Pointer .ls

Text File | 1997-05-10 | 2.1 KB | 60 lines

property outcurs, incurs, incursSet, customImage, customMask, oldcursor

on translate_cursor me, setting
  case setting of
    #none:
      set val to 0
    #arrow:
      set val to -1
    #IBeam:
      set val to 1
    #crosshair:
      set val to 2
    #crossbar:
      set val to 3
    #watch:
      set val to 4
    #invisible:
      set val to 200
    #Custom:
      set val to [member the customImage of me, member the customMask of me]
  end case
  return val
end

on beginSprite me
  set oldcursor to the cursor of sprite the spriteNum of me
  set val to translate_cursor(me, the incursSet of me)
  set the cursor of sprite the spriteNum of me to val
end

on endSprite me
  set the cursor of sprite the spriteNum of me to oldcursor
end

on getPropertyDescriptionList
  set description to [:]
  if the currentSpriteNum = 0 then
    set CursDefault to 0
    set CursMaskDefault to 0
  else
    set memref to the member of sprite the currentSpriteNum
    set castLibNum to the castLibNum of memref
    set CursDefault to member (the memberNum of member memref + 1) of castLib castLibNum
    set CursMaskDefault to member (the memberNum of member memref + 2) of castLib castLibNum
  end if
  addProp(description, #incursSet, [#comment: "Pointer Image:", #format: #symbol, #range: [#none, #arrow, #IBeam, #crosshair, #crossbar, #watch, #invisible, #Custom], #default: #Custom])
  addProp(description, #customImage, [#comment: "Custom Image:", #format: #bitmap, #default: CursDefault])
  addProp(description, #customMask, [#comment: "Custom Mask:", #format: #bitmap, #default: CursMaskDefault])
  return description
end

on getBehaviorDescription
  return "Display a designated Pointer Image when over the sprite.  " & RETURN & "PARAMETERS:" & RETURN & "ΓÇó Pointer Image - built in pointer to be displayed." & RETURN & "ΓÇó Custom Image  - ( optional ) number of castmember used as cursor image.  Ignored when Pointer Image is not set to Custom." & RETURN & "ΓÇó Custom Mask - ( optional ) number of castmember used as mask image.  Ignored when Pointer Image is not set to Custom."
end

on getAssocMembers
  set myPropList to [customImage, customMask]
  return myPropList
end